feat : deploy & config verification script

.env.example

@@ -1,3 +1,7 @@
+# Deployment 
+ACCOUNT=deployer 
+DRY=true  # leave blank to broadcast
+
 # Test rpc_endpoints
 RPC_MAINNET=https://eth.llamarpc.com
 RPC_AVALANCHE=https://api.avax.network/ext/bc/C/rpc

.gitignore

@@ -24,3 +24,5 @@ report/
 
 .DS_Store
 .venv/
+
+output/

Makefile

@@ -29,3 +29,18 @@ coverage :
 	make coverage-clean
 	make coverage-report
 	make coverage-badge
+
+# Deployment
+# Step 1:Pre-deploy LiquidationLogic library (required before deploying spokes)
+# `make deploy-precompile CHAIN=mainnet`
+deploy-precompile :;
+	FOUNDRY_PROFILE=${CHAIN} forge clean && forge script scripts/LibraryPreCompile.s.sol \
+	--rpc-url ${CHAIN} --account ${ACCOUNT} --ffi \
+	$(if ${DRY},, --broadcast --verify) \
+
+# Step 2: Deploy contracts + grant roles to deployer
+# `make deploy-contracts CHAIN=mainnet`
+deploy-contracts :;
+	FOUNDRY_PROFILE=${CHAIN} forge clean && forge script scripts/deploy/AaveV4DeployBatch.s.sol:AaveV4DeployBatchScript \
+	--rpc-url ${CHAIN} --account ${ACCOUNT} --slow \
+	$(if ${DRY},, --broadcast --verify) \

foundry.toml

@@ -3,7 +3,12 @@ src = 'src'
 test = 'tests'
 out = 'out'
 libs = ['lib']
-fs_permissions = [{ access = "read", path = "tests/mocks/JsonBindings.sol" }]
+fs_permissions = [
+  { access = "read", path = "tests/mocks/JsonBindings.sol" },
+  { access = "read", path = "./config" },
+  { access = "read", path = "./out" },
+  { access = "read-write", path = "./output" }
+]
 skip = ["tests/mocks/JsonBindings.sol"]
 solc_version = "0.8.28"
 evm_version = "cancun"
@@ -49,6 +54,8 @@ gas_snapshot_check = true
 test = 'tests/gas'
 isolate = true
 
+[profile.anvil]
+
 [profile.coverage]
 optimizer = true
 optimizer_runs = 444444444444
@@ -71,6 +78,7 @@ zkevm = "${RPC_ZKEVM}"
 gnosis = "${RPC_GNOSIS}"
 bnb = "${RPC_BNB}"
 celo = "${RPC_CELO}"
+anvil = "http://127.0.0.1:8545"
 
 [etherscan]
 mainnet = { key = "${ETHERSCAN_API_KEY_MAINNET}", chainId = 1 }

scripts/LibraryPreCompile.s.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: UNLICENSED
+// Copyright (c) 2025 Aave Labs
+pragma solidity ^0.8.0;
+
+import {Script} from 'forge-std/Script.sol';
+import {console2 as console} from 'forge-std/console2.sol';
+import {SpokeDeployUtils} from 'scripts/SpokeDeployUtils.sol';
+
+/**
+ * @dev Deploy LiquidationLogic library using CREATE2 and save the output
+ *      to FOUNDRY_LIBRARIES env variable in .env file.
+ *      This preprocessing step is required before running the main Deploy script,
+ *      as SpokeInstance depends on LiquidationLogic as an external library.
+ *
+ *      The script will ask you to re-execute if FOUNDRY_LIBRARIES is set but the
+ *      library is not deployed, due to setting mutation of bytecode that could
+ *      result in different library addresses.
+ *
+ * Usage:
+ *   forge script scripts/LibraryPreCompile.s.sol --broadcast --fork-url $RPC --ffi
+ */
+contract LibraryPreCompile is Script {
+  function run() external {
+    bool found = SpokeDeployUtils._librariesPathExists();
+
+    if (found) {
+      address lastLib = SpokeDeployUtils._getLiquidationLogicAddress();
+      if (lastLib.code.length > 0) {
+        console.log('[LibraryPreCompile] LiquidationLogic detected. Skipping re-deployment.');
+        return;
+      } else {
+        SpokeDeployUtils._deleteLibrariesPath();
+        console.log(
+          'LibraryPreCompile: FOUNDRY_LIBRARIES was detected and removed. Please run again to deploy library with a fresh compilation.'
+        );
+        revert('RETRY AGAIN');
+      }
+    }
+
+    vm.startBroadcast();
+    SpokeDeployUtils._deployAndWriteLibrariesConfig();
+    vm.stopBroadcast();
+
+    console.log('LibraryPreCompile: FOUNDRY_LIBRARIES set. Run the main deploy script.');
+  }
+}

scripts/SpokeDeployUtils.sol

@@ -0,0 +1,108 @@
+// SPDX-License-Identifier: UNLICENSED
+// Copyright (c) 2025 Aave Labs
+pragma solidity ^0.8.0;
+
+import {Vm} from 'forge-std/Vm.sol';
+import {Create2Utils} from 'src/deployments/utils/libraries/Create2Utils.sol';
+
+/// @title SpokeDeployUtils
+/// @notice Utilities for deploying LiquidationLogic as an external library.
+/// @dev LiquidationLogic must be deployed before SpokeInstance because SpokeInstance
+/// is compiled with via-ir and has references to the library.
+/// 1. Run LibraryPreCompile.s.sol to deploy library, writes FOUNDRY_LIBRARIES to .env
+/// 2. Run the main deploy script to link via FOUNDRY_LIBRARIES
+library SpokeDeployUtils {
+  Vm internal constant vm = Vm(address(uint160(uint256(keccak256('hevm cheat code')))));
+
+  // ==================== Library Deployment ====================
+
+  /// @notice Deploys LiquidationLogic via CREATE2 with salt=0.
+  /// @dev The CREATE2 factory must already be deployed on the target chain.
+  ///      For Anvil, etch it beforehand (see scripts/deploy/AaveV4DeployBatchAnvil.s.sol).
+  /// @return The deployed library address.
+  function deployLiquidationLogic() internal returns (address) {
+    bytes memory bytecode = vm.getCode('src/spoke/libraries/LiquidationLogic.sol:LiquidationLogic');
+    return Create2Utils.create2Deploy(bytes32(0), bytecode);
+  }
+
+  /// @notice Returns the FOUNDRY_LIBRARIES-compatible string for library linking.
+  function getLibraryString(address liquidationLogic) internal pure returns (string memory) {
+    return
+      string(
+        abi.encodePacked(
+          'src/spoke/libraries/LiquidationLogic.sol:LiquidationLogic:',
+          vm.toString(liquidationLogic)
+        )
+      );
+  }
+
+  /// @notice Deploys LiquidationLogic and appends FOUNDRY_LIBRARIES to .env.
+  function _deployAndWriteLibrariesConfig() internal {
+    address liquidationLogic = deployLiquidationLogic();
+
+    string memory librariesSolcString = getLibraryString(liquidationLogic);
+
+    string memory sedCommand = string(
+      abi.encodePacked('echo FOUNDRY_LIBRARIES=', librariesSolcString, ' >> .env')
+    );
+    string[] memory command = new string[](3);
+
+    command[0] = 'bash';
+    command[1] = '-c';
+    command[2] = string(abi.encodePacked('response="$(', sedCommand, ')"; $response;'));
+    vm.ffi(command);
+  }
+
+  // ==================== .env Management (FFI) ====================
+
+  /// @notice Checks if .env contains a FOUNDRY_LIBRARIES entry.
+  function _librariesPathExists() internal returns (bool) {
+    string
+      memory checkCommand = '[ -e .env ] && grep -q "FOUNDRY_LIBRARIES" .env && echo true || echo false';
+    string[] memory command = new string[](3);
+
+    command[0] = 'bash';
+    command[1] = '-c';
+    command[2] = string(
+      abi.encodePacked(
+        'response="$(',
+        checkCommand,
+        ')"; cast abi-encode "response(bool)" $response;'
+      )
+    );
+    bytes memory res = vm.ffi(command);
+
+    return abi.decode(res, (bool));
+  }
+
+  /// @notice Deletes the FOUNDRY_LIBRARIES line from .env.
+  function _deleteLibrariesPath() internal {
+    string memory deleteCommand = "sed -i.bak -r '/FOUNDRY_LIBRARIES/d' .env && rm .env.bak";
+    string[] memory delCommand = new string[](3);
+
+    delCommand[0] = 'bash';
+    delCommand[1] = '-c';
+    delCommand[2] = string(abi.encodePacked('response="$(', deleteCommand, ')"; $response;'));
+    vm.ffi(delCommand);
+  }
+
+  /// @notice Reads the LiquidationLogic address from FOUNDRY_LIBRARIES in .env.
+  /// @return The address, or address(0) if not found.
+  function _getLiquidationLogicAddress() internal returns (address) {
+    string memory getLibraryAddress = "sed -nr 's/.*LiquidationLogic:([^,]*).*/\\1/p' .env";
+    string[] memory getAddressCommand = new string[](3);
+
+    getAddressCommand[0] = 'bash';
+    getAddressCommand[1] = '-c';
+    getAddressCommand[2] = string(
+      abi.encodePacked(
+        'response="$(',
+        getLibraryAddress,
+        ')"; [ -z "$response" ] && cast abi-encode "response(address)" 0x0000000000000000000000000000000000000000 || cast abi-encode "response(address)" $response'
+      )
+    );
+
+    bytes memory res = vm.ffi(getAddressCommand);
+    return abi.decode(res, (address));
+  }
+}