feat: Add FeeSharesMinter contract

scripts/deploy/AaveV4DeployBatchBase.s.sol

@@ -117,6 +117,10 @@ abstract contract AaveV4DeployBatchBaseScript is Script {
         _logWarning(string.concat('treasury spoke owner', message, outcome));
         sanitizedInputs.treasurySpokeOwner = deployer;
       }
+      if (inputs.feeSharesMinterOwner == address(0)) {
+        _logWarning(string.concat('fee shares minter owner', message, outcome));
+        sanitizedInputs.feeSharesMinterOwner = deployer;
+      }
       if (inputs.spokeAdmin == address(0)) {
         _logWarning(string.concat('spoke admin', message, outcome));
         sanitizedInputs.spokeAdmin = deployer;
@@ -133,6 +137,9 @@ abstract contract AaveV4DeployBatchBaseScript is Script {
       _logWarning(string.concat('treasury spoke owner', message, outcome));
       sanitizedInputs.treasurySpokeOwner = deployer;
 
+      _logWarning(string.concat('fee shares minter owner', message, outcome));
+      sanitizedInputs.feeSharesMinterOwner = deployer;
+
       _logWarning(string.concat('proxy admin owner', message, outcome));
       sanitizedInputs.proxyAdminOwner = deployer;
     }

scripts/deploy/examples/AaveV4DeployAnvil.s.sol

@@ -45,6 +45,7 @@ contract AaveV4DeployAnvil is AaveV4DeployBatchBaseScript {
       hubAdmin: address(0),
       hubConfiguratorAdmin: address(0),
       treasurySpokeOwner: address(0),
+      feeSharesMinterOwner: address(0),
       spokeAdmin: address(0),
       spokeConfiguratorAdmin: address(1),
       gatewayOwner: address(2),

src/dependencies/chainlink/AutomationCompatibleInterface.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: MIT
+// Imported from https://github.com/smartcontractkit/chainlink/blob/v2.22.0/contracts/src/v0.8/automation/interfaces/AutomationCompatibleInterface.sol
+pragma solidity ^0.8.0;
+
+// solhint-disable-next-line interface-starts-with-i
+interface AutomationCompatibleInterface {
+  /**
+   * @notice method that is simulated by the keepers to see if any work actually
+   * needs to be performed. This method does does not actually need to be
+   * executable, and since it is only ever simulated it can consume lots of gas.
+   * @dev To ensure that it is never called, you may want to add the
+   * cannotExecute modifier from KeeperBase to your implementation of this
+   * method.
+   * @param checkData specified in the upkeep registration so it is always the
+   * same for a registered upkeep. This can easily be broken down into specific
+   * arguments using `abi.decode`, so multiple upkeeps can be registered on the
+   * same contract and easily differentiated by the contract.
+   * @return upkeepNeeded boolean to indicate whether the keeper should call
+   * performUpkeep or not.
+   * @return performData bytes that the keeper should call performUpkeep with, if
+   * upkeep is needed. If you would like to encode data to decode later, try
+   * `abi.encode`.
+   */
+  function checkUpkeep(
+    bytes calldata checkData
+  ) external returns (bool upkeepNeeded, bytes memory performData);
+
+  /**
+   * @notice method that is actually executed by the keepers, via the registry.
+   * The data returned by the checkUpkeep simulation will be passed into
+   * this method to actually be executed.
+   * @dev The input to this method should not be trusted, and the caller of the
+   * method should not even be restricted to any single registry. Anyone should
+   * be able call it, and the input should be validated, there is no guarantee
+   * that the data passed in is the performData returned from checkUpkeep. This
+   * could happen due to malicious keepers, racing keepers, or simply a state
+   * change while the performUpkeep transaction is waiting for confirmation.
+   * Always validate the data passed in.
+   * @param performData is the data which was passed back from the checkData
+   * simulation. If it is encoded, it can easily be decoded into other types by
+   * calling `abi.decode`. This data should not be trusted, and should be
+   * validated against the contract's current state.
+   */
+  function performUpkeep(
+    bytes calldata performData
+  ) external;
+}

src/deployments/batches/AaveV4FeeSharesMinterBatch.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity ^0.8.0;
+
+import {BatchReports} from 'src/deployments/libraries/BatchReports.sol';
+import {AaveV4FeeSharesMinterDeployProcedure} from 'src/deployments/procedures/deploy/utils/AaveV4FeeSharesMinterDeployProcedure.sol';
+
+/// @title AaveV4FeeSharesMinterBatch
+/// @author Aave Labs
+/// @notice Deploys the FeeSharesMinter contract, producing a batch report.
+contract AaveV4FeeSharesMinterBatch is AaveV4FeeSharesMinterDeployProcedure {
+  BatchReports.FeeSharesMinterBatchReport internal _report;
+
+  /// @dev Constructor.
+  /// @param owner_ The owner of the FeeSharesMinter.
+  /// @param salt_ The CREATE2 salt for deterministic deployment.
+  constructor(address owner_, bytes32 salt_) {
+    address feeSharesMinter = _deployFeeSharesMinter({owner: owner_, salt: salt_});
+    _report = BatchReports.FeeSharesMinterBatchReport({feeSharesMinter: feeSharesMinter});
+  }
+
+  /// @notice Returns the batch deployment report.
+  function getReport() external view returns (BatchReports.FeeSharesMinterBatchReport memory) {
+    return _report;
+  }
+}

src/deployments/libraries/BatchReports.sol

@@ -40,6 +40,11 @@ library BatchReports {
     address treasurySpoke;
   }
 
+  /// @dev feeSharesMinter The deployed FeeSharesMinter contract address.
+  struct FeeSharesMinterBatchReport {
+    address feeSharesMinter;
+  }
+
   /// @dev signatureGateway The deployed SignatureGateway contract address.
   /// @dev nativeGateway The deployed NativeTokenGateway contract address.
   struct GatewaysBatchReport {

src/deployments/libraries/OrchestrationReports.sol

@@ -24,6 +24,7 @@ library OrchestrationReports {
   /// @dev authorityBatchReport AccessManager deployment report.
   /// @dev configuratorBatchReport Configurator deployment report.
   /// @dev treasurySpokeBatchReport TreasurySpoke deployment report.
+  /// @dev feeSharesMinterBatchReport FeeSharesMinter deployment report.
   /// @dev spokeInstanceBatchReports Per-spoke deployment reports.
   /// @dev hubInstanceBatchReports Per-hub deployment reports.
   /// @dev gatewaysBatchReport Gateway deployment report.
@@ -33,6 +34,7 @@ library OrchestrationReports {
     BatchReports.AuthorityBatchReport authorityBatchReport;
     BatchReports.ConfiguratorBatchReport configuratorBatchReport;
     BatchReports.TreasurySpokeBatchReport treasurySpokeBatchReport;
+    BatchReports.FeeSharesMinterBatchReport feeSharesMinterBatchReport;
     SpokeDeploymentReport[] spokeInstanceBatchReports;
     HubDeploymentReport[] hubInstanceBatchReports;
     BatchReports.GatewaysBatchReport gatewaysBatchReport;

src/deployments/orchestration/AaveV4DeployBase.sol

@@ -11,6 +11,7 @@ import {AaveV4PositionManagerBatch} from 'src/deployments/batches/AaveV4Position
 import {AaveV4SpokeInstanceBatch} from 'src/deployments/batches/AaveV4SpokeInstanceBatch.sol';
 import {AaveV4TokenizationSpokeBatch} from 'src/deployments/batches/AaveV4TokenizationSpokeBatch.sol';
 import {AaveV4TreasurySpokeBatch} from 'src/deployments/batches/AaveV4TreasurySpokeBatch.sol';
+import {AaveV4FeeSharesMinterBatch} from 'src/deployments/batches/AaveV4FeeSharesMinterBatch.sol';
 
 /// @title AaveV4DeployBase Library
 /// @author Aave Labs
@@ -61,6 +62,21 @@ library AaveV4DeployBase {
     return treasurySpokeBatch.getReport();
   }
 
+  /// @notice Deploys the FeeSharesMinter batch containing the FeeSharesMinter contract.
+  /// @param owner The owner of the FeeSharesMinter.
+  /// @param salt The CREATE2 salt for deterministic deployment.
+  /// @return The FeeSharesMinter batch report.
+  function deployFeeSharesMinterBatch(
+    address owner,
+    bytes32 salt
+  ) internal returns (BatchReports.FeeSharesMinterBatchReport memory) {
+    AaveV4FeeSharesMinterBatch feeSharesMinterBatch = new AaveV4FeeSharesMinterBatch({
+      owner_: owner,
+      salt_: salt
+    });
+    return feeSharesMinterBatch.getReport();
+  }
+
   /// @notice Deploys the Hub instance batch containing the Hub proxy, implementation, and IR strategy.
   /// @param proxyAdminOwner The owner of the proxy admin.
   /// @param authority The access-control authority for the Hub.

src/deployments/orchestration/AaveV4DeployOrchestration.sol

@@ -70,6 +70,13 @@ library AaveV4DeployOrchestration {
       salt: salt
     });
 
+    // Deploy FeeSharesMinter Batch (single instance for all hubs)
+    report.feeSharesMinterBatchReport = _deployFeeSharesMinterBatch({
+      logger: logger,
+      feeSharesMinterOwner: deployInputs.feeSharesMinterOwner,
+      salt: salt
+    });
+
     // Validate label uniqueness (duplicate labels produce identical CREATE2 salts)
     InputUtils.validateUniqueLabels(deployInputs.hubLabels, 'hub');
     InputUtils.validateUniqueLabels(deployInputs.spokeLabels, 'spoke');
@@ -340,6 +347,18 @@ library AaveV4DeployOrchestration {
     return report;
   }
 
+  function _deployFeeSharesMinterBatch(
+    Logger logger,
+    address feeSharesMinterOwner,
+    bytes32 salt
+  ) internal returns (BatchReports.FeeSharesMinterBatchReport memory report) {
+    logger.logHeader1('deploying FeeSharesMinterBatch');
+    report = AaveV4DeployBase.deployFeeSharesMinterBatch({owner: feeSharesMinterOwner, salt: salt});
+    logger.log('FeeSharesMinter', report.feeSharesMinter);
+    logger.logNewLine();
+    return report;
+  }
+
   function _deployGatewayBatch(
     Logger logger,
     address gatewayOwner,

src/deployments/procedures/deploy/utils/AaveV4FeeSharesMinterDeployProcedure.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity ^0.8.0;
+
+import {AaveV4DeployProcedureBase} from 'src/deployments/procedures/AaveV4DeployProcedureBase.sol';
+import {Create2Utils} from 'src/deployments/utils/libraries/Create2Utils.sol';
+import {FeeSharesMinter} from 'src/utils/FeeSharesMinter.sol';
+
+/// @title AaveV4FeeSharesMinterDeployProcedure
+/// @author Aave Labs
+/// @notice Deploys the FeeSharesMinter contract.
+contract AaveV4FeeSharesMinterDeployProcedure is AaveV4DeployProcedureBase {
+  /// @notice Deploys a new FeeSharesMinter instance via CREATE2.
+  /// @param owner The owner of the FeeSharesMinter.
+  /// @param salt The CREATE2 salt for deterministic deployment.
+  /// @return The address of the deployed FeeSharesMinter contract.
+  function _deployFeeSharesMinter(address owner, bytes32 salt) internal returns (address) {
+    require(owner != address(0), 'invalid owner');
+    return
+      Create2Utils.create2Deploy({
+        salt: salt,
+        bytecode: abi.encodePacked(type(FeeSharesMinter).creationCode, abi.encode(owner))
+      });
+  }
+}

src/deployments/utils/MetadataLogger.sol

@@ -20,6 +20,7 @@ contract MetadataLogger is Logger {
     _write('hubConfigurator', report.configuratorBatchReport.hubConfigurator);
     _write('spokeConfigurator', report.configuratorBatchReport.spokeConfigurator);
     _write('treasurySpoke', report.treasurySpokeBatchReport.treasurySpoke);
+    _write('feeSharesMinter', report.feeSharesMinterBatchReport.feeSharesMinter);
 
     // Group hubs by property type
     uint256 hubLen = report.hubInstanceBatchReports.length;

src/deployments/utils/libraries/InputUtils.sol

@@ -12,6 +12,8 @@ library InputUtils {
   /// @dev hubConfiguratorAdmin The admin granted all hub configurator roles. Only used when grantRoles is true.
   /// @dev treasurySpokeOwner The owner of the TreasurySpoke (Ownable). Required at deploy time (constructor arg).
   ///      When grantRoles is `false`, defaults to the deployer; ownership can be transferred post-deployment.
+  /// @dev feeSharesMinterOwner The owner of the FeeSharesMinter (Ownable). Required at deploy time (constructor arg).
+  ///      When grantRoles is `false`, defaults to the deployer; ownership can be transferred post-deployment.
   /// @dev spokeAdmin The spoke admin. Only used when grantRoles is true.
   /// @dev spokeConfiguratorAdmin The admin granted all spoke configurator roles. Only used when grantRoles is true.
   /// @dev gatewayOwner The owner of the native token and signature gateways.
@@ -34,6 +36,7 @@ library InputUtils {
     address hubAdmin;
     address hubConfiguratorAdmin;
     address treasurySpokeOwner;
+    address feeSharesMinterOwner;
     address spokeAdmin;
     address spokeConfiguratorAdmin;
     address gatewayOwner;

src/utils/FeeSharesMinter.sol

@@ -0,0 +1,89 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity 0.8.28;
+
+import {Ownable2Step, Ownable} from 'src/dependencies/openzeppelin/Ownable2Step.sol';
+import {PercentageMath} from 'src/libraries/math/PercentageMath.sol';
+import {Rescuable} from 'src/utils/Rescuable.sol';
+import {IFeeSharesMinter} from 'src/utils/IFeeSharesMinter.sol';
+import {IHub} from 'src/hub/interfaces/IHub.sol';
+
+/// @title FeeSharesMinter
+/// @author Aave Labs
+/// @notice Contract to mint fee shares on the Hub when specific conditions are met.
+contract FeeSharesMinter is IFeeSharesMinter, Ownable2Step, Rescuable {
+  mapping(address hub => mapping(uint256 assetId => uint16)) internal _minAccruedFeesPercent;
+
+  /// @dev Constructor.
+  /// @param owner The owner of the contract.
+  constructor(address owner) Ownable(owner) {}
+
+  /// @inheritdoc IFeeSharesMinter
+  function setConfig(
+    address hub,
+    uint256 assetId,
+    uint16 minAccruedFeesPercent
+  ) external onlyOwner {
+    require(minAccruedFeesPercent <= PercentageMath.PERCENTAGE_FACTOR, InvalidConfig());
+    _minAccruedFeesPercent[hub][assetId] = minAccruedFeesPercent;
+    emit ConfigUpdated(hub, assetId, minAccruedFeesPercent);
+  }
+
+  /// @inheritdoc IFeeSharesMinter
+  function performUpkeep(bytes calldata performData) external override {
+    (address hub, uint256 assetId) = abi.decode(performData, (address, uint256));
+    _performUpkeep(hub, assetId);
+  }
+
+  /// @inheritdoc IFeeSharesMinter
+  function checkUpkeep(
+    bytes calldata checkData
+  ) external view override returns (bool, bytes memory) {
+    (address hub, uint256 assetId) = abi.decode(checkData, (address, uint256));
+    bool upkeepNeeded = _checkUpkeep(hub, assetId);
+    bytes memory performData = checkData;
+    return (upkeepNeeded, performData);
+  }
+
+  /// @inheritdoc IFeeSharesMinter
+  function getConfig(address hub, uint256 assetId) external view returns (uint16) {
+    return _minAccruedFeesPercent[hub][assetId];
+  }
+
+  /// @dev Internal function to execute fee share minting.
+  /// @param hub The address of the hub.
+  /// @param assetId The identifier of the asset.
+  function _performUpkeep(address hub, uint256 assetId) internal virtual {
+    require(_checkUpkeep(hub, assetId), ConditionsNotMet());
+
+    IHub(hub).mintFeeShares(assetId);
+  }
+
+  /// @dev Internal function to check execution conditions.
+  /// @param hub The address of the hub.
+  /// @param assetId The identifier of the asset.
+  /// @return True if conditions are met, false otherwise.
+  function _checkUpkeep(address hub, uint256 assetId) internal view virtual returns (bool) {
+    uint16 minAccruedFeesPercent = _minAccruedFeesPercent[hub][assetId];
+
+    IHub hubContract = IHub(hub);
+    uint256 accruedFees = hubContract.getAssetAccruedFees(assetId);
+    uint256 totalAddedAssets = hubContract.getAddedAssets(assetId);
+
+    if (totalAddedAssets == 0) {
+      return false;
+    }
+    if (PercentageMath.percentDivDown(accruedFees, totalAddedAssets) < minAccruedFeesPercent) {
+      return false;
+    }
+
+    // Ensure at least 1 fee share would be minted
+    uint256 expectedShares = hubContract.previewAddByAssets(assetId, accruedFees);
+
+    return expectedShares > 0;
+  }
+
+  /// @inheritdoc Rescuable
+  function _rescueGuardian() internal view override returns (address) {
+    return owner();
+  }
+}

src/utils/IFeeSharesMinter.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: LicenseRef-BUSL
+pragma solidity 0.8.28;
+
+import {AutomationCompatibleInterface} from 'src/dependencies/chainlink/AutomationCompatibleInterface.sol';
+
+/// @title IFeeSharesMinter
+/// @author Aave Labs
+/// @notice Interface for the FeeSharesMinter contract
+interface IFeeSharesMinter is AutomationCompatibleInterface {
+  /// @notice Emitted when the configuration for an asset is updated.
+  /// @param hub The address of the hub.
+  /// @param assetId The identifier of the asset.
+  /// @param minAccruedFeesPercent The new minimum ratio of accrued fees to total added assets, in BPS.
+  event ConfigUpdated(address indexed hub, uint256 indexed assetId, uint16 minAccruedFeesPercent);
+
+  /// @notice Thrown upon minting when the required conditions are not met.
+  error ConditionsNotMet();
+
+  /// @notice Thrown when `setConfig` is called with an invalid value.
+  error InvalidConfig();
+
+  /// @notice Sets the minimum accrued fees percent for a specific asset.
+  /// @param hub The address of the hub.
+  /// @param assetId The identifier of the asset.
+  /// @param minAccruedFeesPercent Minimum ratio of accrued fees to total added assets, in BPS.
+  function setConfig(address hub, uint256 assetId, uint16 minAccruedFeesPercent) external;
+
+  /// @notice Chainlink Automation on-chain execution entry point.
+  /// @dev performData must be abi.encoded as (address hub, uint256 assetId).
+  /// @inheritdoc AutomationCompatibleInterface
+  function performUpkeep(bytes calldata performData) external;
+
+  /// @notice Chainlink Automation off-chain simulation check.
+  /// @dev checkData must be abi.encoded as (address hub, uint256 assetId).
+  /// @dev Returns whether upkeep is needed and the performData in bytes when conditions are met.
+  /// @inheritdoc AutomationCompatibleInterface
+  function checkUpkeep(
+    bytes calldata checkData
+  ) external view returns (bool upkeepNeeded, bytes memory performData);
+
+  /// @notice Returns the minimum accrued fees percent for a specific asset.
+  /// @param hub The address of the hub.
+  /// @param assetId The identifier of the asset.
+  /// @return The minimum ratio of accrued fees to total added assets, in BPS.
+  function getConfig(address hub, uint256 assetId) external view returns (uint16);
+}