[cmake] download instead of bundle gl2ps and bump from 1.3.1 to 1.4.2, and use CMake target

[cmake] simplify dependency check

matches 6.40 release notes

[cmake] use canonical names

[cmake] fix case

[cmake] fix case and simplify check

[graf3d] add dependency on builtin

[cmake] simplify check

[cmake] fix freetype builtins

[cmake] fix deprecation error

[gl2ps] do not depend on PNG or ZLIB

since only EPS backend is used by ROOT graf3d plotter

Author: ferdymercury

builtins/gl2ps/CMakeLists.txt

@@ -0,0 +1,59 @@
+# Copyright (C) 1995-2026, Rene Brun and Fons Rademakers.
+# All rights reserved.
+#
+# For the licensing terms see $ROOTSYS/LICENSE.
+# For the list of contributors see $ROOTSYS/README/CREDITS.
+
+# **PLEASE UPDATE ALSO THE FOLLOWING LINE WHEN UPDATING THE VERSION**
+# 30 Apr 2020, https://gitlab.onelab.info/gl2ps/gl2ps/-/releases/gl2ps_1_4_2
+set(ROOT_GL2PS_VERSION 1.4.2)
+set(ROOT_GL2PS_HASH "afb6f4a8df9c7639449546a79aabd1baaccacc4360fc23741c6485138512ff72")
+
+set(ROOT_GL2PS_PREFIX ${CMAKE_BINARY_DIR}/builtins/GL2PS-prefix)
+
+set(ROOT_GL2PS_LIBRARY ${ROOT_GL2PS_PREFIX}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}gl2ps${CMAKE_STATIC_LIBRARY_SUFFIX}
+)
+
+if(WIN32 AND NOT CMAKE_GENERATOR MATCHES Ninja)
+  if(winrtdebug)
+    set(ROOT_GL2PS_BUILD_COMMAND_FLAGS "--config Debug")
+  else()
+    set(ROOT_GL2PS_BUILD_COMMAND_FLAGS "--config $<IF:$<CONFIG:Debug,RelWithDebInfo>,RelWithDebInfo,Release>")
+  endif()
+endif()
+
+ExternalProject_Add(
+  BUILTIN_GL2PS
+  PREFIX ${ROOT_GL2PS_PREFIX}
+  URL ${lcgpackages}/gl2ps-${ROOT_GL2PS_VERSION}.tar.gz
+  URL_HASH SHA256=${ROOT_GL2PS_HASH}
+  CMAKE_ARGS -G ${CMAKE_GENERATOR}
+             -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+             -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
+             -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+             -DCMAKE_C_VISIBILITY_PRESET=hidden
+             -DCMAKE_POLICY_VERSION_MINIMUM=3.5
+             -DENABLE_PNG=OFF
+             -DENABLE_ZLIB=OFF
+  BUILD_COMMAND ${CMAKE_COMMAND} --build . ${ROOT_GL2PS_BUILD_COMMAND_FLAGS}
+  INSTALL_COMMAND ${CMAKE_COMMAND} --build . ${ROOT_GL2PS_BUILD_COMMAND_FLAGS} --target install
+  LOG_CONFIGURE 1
+  LOG_BUILD 1
+  LOG_INSTALL 1
+  LOG_OUTPUT_ON_FAILURE 1
+  BUILD_BYPRODUCTS ${ROOT_GL2PS_LIBRARY}
+  TIMEOUT 600)
+
+file(MAKE_DIRECTORY ${ROOT_GL2PS_PREFIX}/include)
+add_library(gl2ps::gl2ps IMPORTED STATIC GLOBAL)
+set_target_properties(gl2ps::gl2ps PROPERTIES
+    IMPORTED_LOCATION ${ROOT_GL2PS_LIBRARY}
+    INTERFACE_INCLUDE_DIRECTORIES ${ROOT_GL2PS_PREFIX}/include)
+set_property(GLOBAL APPEND PROPERTY ROOT_BUILTIN_TARGETS gl2ps::gl2ps)
+
+# Set the canonical output of find_package according to
+# https://cmake.org/cmake/help/latest/manual/cmake-developer.7.html#standard-variable-names
+set(gl2ps_INCLUDE_DIRS ${ROOT_GL2PS_PREFIX}/include PARENT_SCOPE)
+set(gl2ps_LIBRARIES ${ROOT_GL2PS_LIBRARY} PARENT_SCOPE)
+set(gl2ps_FOUND TRUE PARENT_SCOPE)
+set(gl2ps_VERSION ${ROOT_GL2PS_VERSION} PARENT_SCOPE)

cmake/modules/Findgl2ps.cmake

@@ -7,23 +7,32 @@
 # - Locate gl2ps library
 # Defines:
 #
-#  GL2PS_FOUND
-#  GL2PS_INCLUDE_DIR
-#  GL2PS_INCLUDE_DIRS (not cached)
-#  GL2PS_LIBRARIES
+#  gl2ps_FOUND
+#  gl2ps_INCLUDE_DIR
+#  gl2ps_INCLUDE_DIRS (not cached)
+#  gl2ps_LIBRARIES
 
-find_path(GL2PS_INCLUDE_DIR NAMES gl2ps.h HINTS ${GL2PS_DIR}/include $ENV{GL2PS_DIR}/include /usr/include)
-find_library(GL2PS_LIBRARY NAMES gl2ps HINTS ${GL2PS_DIR}/lib $ENV{GL2PS_DIR}/lib)
+find_path(gl2ps_INCLUDE_DIR NAMES gl2ps.h HINTS ${gl2ps_DIR}/include $ENV{gl2ps_DIR}/include /usr/include)
+find_library(gl2ps_LIBRARY NAMES gl2ps HINTS ${gl2ps_DIR}/lib $ENV{gl2ps_DIR}/lib)
 
-set(GL2PS_INCLUDE_DIRS ${GL2PS_INCLUDE_DIR})
-if(GL2PS_LIBRARY)
-  set(GL2PS_LIBRARIES ${GL2PS_LIBRARY})
+set(gl2ps_INCLUDE_DIRS ${gl2ps_INCLUDE_DIR})
+if(gl2ps_LIBRARY)
+  set(gl2ps_LIBRARIES ${gl2ps_LIBRARY})
 endif()
 
 
-# handle the QUIETLY and REQUIRED arguments and set GL2PS_FOUND to TRUE if
+# handle the QUIETLY and REQUIRED arguments and set gl2ps_FOUND to TRUE if
 # all listed variables are TRUE
 INCLUDE(FindPackageHandleStandardArgs)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(gl2ps DEFAULT_MSG GL2PS_LIBRARY GL2PS_INCLUDE_DIR)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(gl2ps DEFAULT_MSG gl2ps_LIBRARY gl2ps_INCLUDE_DIR)
 
-mark_as_advanced(GL2PS_FOUND GL2PS_INCLUDE_DIR GL2PS_LIBRARY)
+mark_as_advanced(gl2ps_FOUND gl2ps_INCLUDE_DIR gl2ps_LIBRARY)
+
+if(gl2ps_FOUND)
+  if(NOT TARGET gl2ps::g2ps)
+    add_library(gl2ps::gl2ps UNKNOWN IMPORTED)
+    set_target_properties(gl2ps::gl2ps PROPERTIES
+      IMPORTED_LOCATION "${gl2ps_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${gl2ps_INCLUDE_DIR}")
+  endif()
+endif()

cmake/modules/SearchInstalledSoftware.cmake

@@ -260,7 +260,7 @@ if(NOT builtin_freetype)
 endif()
 
 if(builtin_freetype)
-  list(APPEND ROOT_BUILTINS FREETYPE)
+  list(APPEND ROOT_BUILTINS BUILTIN_FREETYPE)
   add_subdirectory(builtins/freetype)
 endif()
 
@@ -567,16 +567,11 @@ if(opengl AND NOT asimage)
 endif()
 
 #---Check for gl2ps ------------------------------------------------------------------
-if(opengl AND NOT builtin_gl2ps)
-  message(STATUS "Looking for gl2ps")
-  if(fail-on-missing)
-    find_Package(gl2ps REQUIRED)
-  else()
-    find_Package(gl2ps)
-    if(NOT GL2PS_FOUND)
-      message(STATUS "gl2ps not found. Switching on builtin_gl2ps option")
-      set(builtin_gl2ps ON CACHE BOOL "Enabled because opengl requested and gl2ps not found (${builtin_gl2ps_description})" FORCE)
-    endif()
+if(opengl)
+  ROOT_FIND_REQUIRED_DEP(gl2ps builtin_gl2ps)
+  if (builtin_gl2ps)
+    add_subdirectory(builtins/gl2ps)
+    list(APPEND ROOT_BUILTINS BUILTIN_GL2PS)
   endif()
 endif()
 

graf3d/gl/CMakeLists.txt

@@ -17,11 +17,6 @@ if(x11)
   set(RGL_EXTRA_SOURCES TX11GL.cxx)
 endif()
 
-
-if(builtin_gl2ps)
-  set(RGL_EXTRA_SOURCES ${RGL_EXTRA_SOURCES} src/gl2ps.cxx)
-endif()
-
 set_source_files_properties(src/TGLFontManager.cxx PROPERTIES COMPILE_FLAGS "${FTGL_CFLAGS}")
 set_source_files_properties(src/TGLText.cxx PROPERTIES COMPILE_FLAGS "${FTGL_CFLAGS}")
 
@@ -208,7 +203,7 @@ ROOT_STANDARD_LIBRARY_PACKAGE(RGL
     OpenGL::GL
     OpenGL::GLU
     ${FTGL_LIBRARIES}
-    ${GL2PS_LIBRARIES}
+    gl2ps::gl2ps
     Freetype::Freetype
     ZLIB::ZLIB
     ${X11_LIBRARIES}
@@ -219,21 +214,18 @@ ROOT_STANDARD_LIBRARY_PACKAGE(RGL
     Ged
     RCsg
     ASImage
+  BUILTINS
+    BUILTIN_GL2PS
   INSTALL_OPTIONS
     ${installoptions}
 )
 
+
 target_include_directories(RGL PRIVATE
      ${OPENGL_INCLUDE_DIR}
      ${FTGL_INCLUDE_DIR}
 )
 
-if(builtin_gl2ps)
-  target_include_directories(RGL PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src/gl2ps)
-else()
-  target_include_directories(RGL PRIVATE ${GL2PS_INCLUDE_DIRS})
-endif()
-
 if(MACOSX_GLU_DEPRECATED)
   target_compile_options(RGL PRIVATE -Wno-deprecated-declarations)
 endif()