arbor/justfile at main · penso/arbor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
default:
    @just --list

nightly_toolchain := "nightly-2025-11-30"
web_ui_dir := "crates/arbor-web-ui/app"

setup-macos:
    xcodebuild -downloadComponent MetalToolchain
    brew install --cask font-caskaydia-cove-nerd-font

setup-linux:
    sudo apt-get update
    sudo apt-get install -y libxcb1-dev libxkbcommon-dev libxkbcommon-x11-dev
    #!/usr/bin/env bash
    set -euo pipefail
    FONT_DIR="${HOME}/.local/share/fonts"
    mkdir -p "${FONT_DIR}"
    curl -fLo /tmp/CascadiaCode.tar.xz https://github.com/ryanoasis/nerd-fonts/releases/latest/download/CascadiaCode.tar.xz
    tar -xf /tmp/CascadiaCode.tar.xz -C "${FONT_DIR}"
    rm /tmp/CascadiaCode.tar.xz
    fc-cache -fv

format:
    cargo +{{nightly_toolchain}} fmt --all

format-check:
    cargo +{{nightly_toolchain}} fmt --all -- --check

lockfile-check:
    cargo fetch --locked

lint: lockfile-check
    cargo +{{nightly_toolchain}} clippy --workspace --all-features --all-targets -- -D warnings

test:
    cargo +{{nightly_toolchain}} test --workspace

ghostty-vt-bridge:
    ./scripts/build-ghostty-vt-bridge.sh

test-ghostty-vt: ghostty-vt-bridge
    RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}" cargo +{{nightly_toolchain}} test -p arbor-terminal-emulator --features ghostty-vt-experimental

check-ghostty-vt-gui: ghostty-vt-bridge
    ARBOR_BUILD_BRANCH="$(git branch --show-current 2>/dev/null || true)" RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}" cargo +{{nightly_toolchain}} check -p arbor-gui --features ghostty-vt-experimental

check-ghostty-vt-httpd: ghostty-vt-bridge
    RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}" cargo +{{nightly_toolchain}} check -p arbor-httpd --features ghostty-vt-experimental

bench-embedded-terminal-engines: ghostty-vt-bridge
    RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}" cargo +{{nightly_toolchain}} test -p arbor-terminal-emulator --features ghostty-vt-experimental --test engine_performance -- --ignored --nocapture

bench-terminal-workloads:
    cargo +{{nightly_toolchain}} test -p arbor-terminal-emulator --test workload_benchmark -- --ignored --nocapture

bench-gui-terminal-workloads:
    cargo +{{nightly_toolchain}} test -p arbor-gui benchmark_resume_scroll_gui_feedback_loop -- --ignored --nocapture

bench-embedded-terminal-codspeed: ghostty-vt-bridge
    RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}" cargo +{{nightly_toolchain}} bench -p arbor-benchmarks --features ghostty-vt-experimental --bench embedded_terminal

docs-build:
    mdbook build docs

docs-serve:
    mdbook serve docs --hostname 127.0.0.1 --port 3003

zizmor:
    zizmor .github/workflows/

ci: format-check lint test

run-configured-embedded-engine port="": web-ui-build-if-needed ghostty-vt-bridge
    #!/usr/bin/env bash
    set -euo pipefail
    if [ -z "{{port}}" ]; then
      DAEMON_PORT=$(python3 -c 'import socket; s=socket.socket(); s.bind(("",0)); print(s.getsockname()[1]); s.close()')
    else
      DAEMON_PORT="{{port}}"
    fi
    echo "daemon port: $DAEMON_PORT"
    export ARBOR_DAEMON_URL="http://127.0.0.1:${DAEMON_PORT}"
    export ARBOR_HTTPD_PORT="${DAEMON_PORT}"
    export ARBOR_BUILD_BRANCH="$(git branch --show-current 2>/dev/null || true)"
    export RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}"
    cargo +{{nightly_toolchain}} run -p arbor-httpd --features ghostty-vt-experimental,agent-chat &
    HTTPD_PID=$!
    trap "kill $HTTPD_PID 2>/dev/null" EXIT
    cargo +{{nightly_toolchain}} run -p arbor-gui --features ghostty-vt-experimental,agent-chat
    kill $HTTPD_PID 2>/dev/null || true

run-ghostty-vt port="": web-ui-build-if-needed ghostty-vt-bridge
    #!/usr/bin/env bash
    set -euo pipefail
    if [ -z "{{port}}" ]; then
      DAEMON_PORT=$(python3 -c 'import socket; s=socket.socket(); s.bind(("",0)); print(s.getsockname()[1]); s.close()')
    else
      DAEMON_PORT="{{port}}"
    fi
    echo "daemon port: $DAEMON_PORT"
    export ARBOR_DAEMON_URL="http://127.0.0.1:${DAEMON_PORT}"
    export ARBOR_HTTPD_PORT="${DAEMON_PORT}"
    export ARBOR_TERMINAL_ENGINE="ghostty-vt-experimental"
    export ARBOR_BUILD_BRANCH="$(git branch --show-current 2>/dev/null || true)"
    export RUSTFLAGS="-L native=$(pwd)/target/ghostty-vt-bridge/lib -C link-arg=-Wl,-rpath,$(pwd)/target/ghostty-vt-bridge/lib ${RUSTFLAGS:-}"
    cargo +{{nightly_toolchain}} run -p arbor-httpd --features ghostty-vt-experimental,agent-chat &
    HTTPD_PID=$!
    trap "kill $HTTPD_PID 2>/dev/null" EXIT
    cargo +{{nightly_toolchain}} run -p arbor-gui --features ghostty-vt-experimental,agent-chat
    kill $HTTPD_PID 2>/dev/null || true

run port="": web-ui-build-if-needed
    #!/usr/bin/env bash
    set -euo pipefail
    if [ -z "{{port}}" ]; then
      DAEMON_PORT=$(python3 -c 'import socket; s=socket.socket(); s.bind(("",0)); print(s.getsockname()[1]); s.close()')
    else
      DAEMON_PORT="{{port}}"
    fi
    echo "daemon port: $DAEMON_PORT"
    export ARBOR_DAEMON_URL="http://127.0.0.1:${DAEMON_PORT}"
    export ARBOR_HTTPD_PORT="${DAEMON_PORT}"
    export ARBOR_BUILD_BRANCH="$(git branch --show-current 2>/dev/null || true)"
    cargo +{{nightly_toolchain}} run -p arbor-httpd --features agent-chat &
    HTTPD_PID=$!
    trap "kill $HTTPD_PID 2>/dev/null" EXIT
    cargo +{{nightly_toolchain}} run -p arbor-gui --features agent-chat
    kill $HTTPD_PID 2>/dev/null || true

web-ui-build:
    cd {{web_ui_dir}} && npm install --no-audit --no-fund && npm run build

web-ui-build-if-needed:
    @if [ -f {{web_ui_dir}}/dist/index.html ]; then \
      echo "web-ui assets already built"; \
    else \
      cd {{web_ui_dir}} && npm install --no-audit --no-fund && npm run build; \
    fi

build-release: web-ui-build-if-needed
    ARBOR_BUILD_BRANCH="$(git branch --show-current 2>/dev/null || true)" cargo +{{nightly_toolchain}} build --release -p arbor-gui -p arbor-httpd

run-httpd: web-ui-build-if-needed
    cargo +{{nightly_toolchain}} run -p arbor-httpd

run-mcp port="": web-ui-build-if-needed
    #!/usr/bin/env bash
    set -euo pipefail
    if [ -z "{{port}}" ]; then
      DAEMON_PORT=$(python3 -c 'import socket; s=socket.socket(); s.bind(("",0)); print(s.getsockname()[1]); s.close()')
    else
      DAEMON_PORT="{{port}}"
    fi
    export ARBOR_DAEMON_URL="http://127.0.0.1:${DAEMON_PORT}"
    export ARBOR_HTTPD_PORT="${DAEMON_PORT}"
    cargo +{{nightly_toolchain}} run -p arbor-httpd &
    HTTPD_PID=$!
    trap "kill $HTTPD_PID 2>/dev/null" EXIT
    cargo +{{nightly_toolchain}} run -p arbor-mcp --features stdio-server

perf-harness action="start" mode="dashboard":
    ./scripts/dev/arbor-perf-harness.sh "{{action}}" "{{mode}}"

changelog:
    git-cliff --config cliff.toml

changelog-unreleased:
    git-cliff --config cliff.toml --unreleased

changelog-file output:
    git-cliff --config cliff.toml --output "{{output}}"

changelog-release version:
    git-cliff --config cliff.toml --unreleased --tag "{{version}}" --strip all