eyetracking-data/build.gradle at master · m2ci-msp/eyetracking-data · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
allprojects {
    apply plugin: 'base'
}

subprojects {
    ext {
        praatMargins = [
                left                       : 106,
                right                      : 1814,
                top                        : 122,
                spectrogramTop             : 464,
                spectrogramUpperBandBottom : 565,
                spectrogramMiddleBandBottom: 770,
                spectrogramBottom          : 805,
                bottom                     : 1049
        ]
        praatMargins.width = praatMargins.right - praatMargins.left
    }

    repositories {
        ['cloudark', 'localhost'].each { host ->
            maven {
                url "http://$host:8081/artifactory/local"
                credentials {
                    username = findProperty('cloudarkUser')
                    password = findProperty('cloudarkApiKey')
                }
            }
        }
    }

    configurations {
        data
    }

    dependencies {
        data group: 'org.m2ci.msp.eyetracking', name: "eyetracking-multimedia-$project.name", version: '1.0', ext: 'mkv'
        data group: 'org.m2ci.msp.eyetracking', name: "raw-data-$project.name-praat", version: '0.1.1', ext: 'zip'
        data group: 'org.m2ci.msp.eyetracking', name: "raw-data-$project.name-textgrid", version: '0.1', ext: 'zip'
        data group: 'org.m2ci.msp.eyetracking', name: "raw-data-$project.name-tobii", version: '0.1', ext: 'zip'
    }

    task unpackData(type: UnpackData) {
        destDir = layout.buildDirectory.dir('rawData')
        praatLogFile = destDir.file('praat.log')
        tobiiLogFile = destDir.file('Audio_Data_Export.tsv')
        screenCaptureFile = destDir.file('screencapture.mp4')
        audioFile = destDir.file('audio.flac')
    }

    task convertPraatLogToYaml(type: ConvertPraatLogToYaml) {
        srcFile = unpackData.praatLogFile
        destFile = layout.buildDirectory.file('data/praat.yaml')
    }

    task convertTobiiLog(type: ConvertTobiiLog) {
        srcFile = unpackData.tobiiLogFile
        destFile = layout.buildDirectory.file('data/Tobii.json')
    }

    task extractScenes(type: ExtractScenes) {
        srcFile = convertPraatLogToYaml.destFile
        destFile = layout.buildDirectory.file('data/scenes.yaml')
    }

    task generatePraatScenes(type: GeneratePraatScenes) {
        scenesFile = extractScenes.destFile
        audioFile = file("$rootDir/src/experiment/northwind_rm.flac")
        destDir = layout.buildDirectory.dir('scenes')
    }

    task generateSceneVideoSegments(type: GenerateSceneVideoSegments) {
        scenesFile = extractScenes.destFile
        inputDir = generatePraatScenes.destDir
        destDir = layout.buildDirectory.dir('sceneVideos')
        finalVideoFile = layout.buildDirectory.file('sceneMovie.mp4')
    }

    task convertScenesToSrt(type: ConvertScenesToSrt) {
        srcFile = extractScenes.destFile
        destFile = layout.buildDirectory.file('data/scenes.srt')
    }

    task mergeTobiiandPraatLogs(type: MergeLogs) {
        praatFile = extractScenes.destFile
        tobiiFile = convertTobiiLog.destFile
        destFile = layout.buildDirectory.file('data/mergedData.yaml')
    }

    task drawGazes(type: DrawGazes) {
        srcFile = generateSceneVideoSegments.finalVideoFile
        gazeFile = mergeTobiiandPraatLogs.destFile
        fixSymbol = file("$rootDir/src/images/red_circle.png")
        destFile = layout.buildDirectory.file('data/gazeVideo.mp4')
    }

    task findOffsets(type: FindOffsets) {
        praatlog = unpackData.praatLogFile
        tobiilog = unpackData.tobiiLogFile
    }

    task muxStreams(type: MuxStreams) {
        gazeVideoFile = drawGazes.destFile
        screenCaptureFile = unpackData.screenCaptureFile
        audioFile = unpackData.audioFile
        subtitleFile = convertScenesToSrt.destFile
        destFile = layout.buildDirectory.file("data/${project.name}.mkv")
    }

    artifacts {
        'default' muxStreams.destFile, {
            builtBy muxStreams
        }
    }
}

task assembleData(type: AssembleData) {
    srcFiles = files(subprojects.collect { it.mergeTobiiandPraatLogs.destFile })
    destFile = layout.buildDirectory.file("${project.name}.yaml")
}

task packageData(type: Zip) {
    from assembleData
    from rootDir, {
        include 'README.md', 'LICENSE.md', 'CHANGELOG.md'
    }
}

artifacts {
    'default' packageData
}