mathlib4/MathlibTest/Contrapose.lean at 408a7a00a9cbd3abffade6a7a789487887621817 · leanprover-community/mathlib4 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
/-
Copyright (c) 2022 Jireh Loreaux. All rights reserved.
Released under Apache 2.0 license as described in the file LICENSE.
Authors: Jireh Loreaux
-/
module
import Mathlib.Tactic.Basic
import Mathlib.Tactic.Contrapose

example (p q : Prop) (h : ¬q → ¬p) : p → q := by
  contrapose
  guard_target = ¬q → ¬p
  exact h

example (p q : Prop) (h : p) (hpq : ¬q → ¬p) : q := by
  contrapose h
  guard_target = ¬p
  exact hpq h

example (p q : Prop) (h : p) (hpq : ¬q → ¬p) : q := by
  contrapose h with h'
  guard_target = ¬p
  exact hpq h'

example (p q : Prop) (h : q → p) : ¬p → ¬q := by
  contrapose
  guard_target = q → p
  exact h

example (p q : Prop) (h : q → ¬p) : p → ¬q := by
  contrapose
  guard_target = q → ¬p
  exact h

example (p q : Prop) (h : ¬q → p) : ¬p → q := by
  contrapose
  guard_target = ¬q → p
  exact h

example (p q : Prop) (h : q → p) : ¬p → ¬q := by
  contrapose
  guard_target = q → p
  exact h

example (p q : Prop) (h : ¬p) (hpq : q → p) : ¬q := by
  contrapose h
  guard_target = p
  exact hpq h

example (p q : Prop) (h : ¬p) (hpq : q → p) : ¬q := by
  contrapose h with h'
  guard_target = p
  exact hpq h'

example (p q : Prop) (h : q → p) : ¬p → ¬q := by
  contrapose
  guard_target = q → p
  exact h

section -- Using contrapose in a superfluous way warns.

/-- warning: `push` made no progress on the goal -/
#guard_msgs in
example (p q : Prop) (h : ¬p) (hpq : q → p) : ¬q := by
  contrapose! h
  guard_target = p
  exact hpq h

/-- warning: `push` made no progress on the goal -/
#guard_msgs in
example (p q : Prop) (h : ¬p) (hpq : q → p) : ¬q := by
  contrapose! h with h'
  guard_target = p
  exact hpq h'

end

example (p q r : Prop) (h : ¬ q ∧ ¬ r → ¬ p) : p → q ∨ r := by
  fail_if_success (contrapose; exact h)
  contrapose!; exact h

/--
error: Tactic `contrapose` failed: the goal `p` is not of the form `_ → _` or `_ ↔ _`

p : Prop
h : p
⊢ p
-/
#guard_msgs in
example (p : Prop) (h : p) : p := by
  contrapose
  exact h

/--
error: Tactic `contrapose` failed: hypothesis `p` is not a proposition

p q : Type
h : p → q
⊢ p → q
-/
#guard_msgs in
example (p q : Type) (h : p → q) : p → q := by
  contrapose
  exact h

/--
error: Tactic `contrapose` failed: the goal `∀ (h : p), q h` is a dependent arrow

p : Prop
q : p → Prop
⊢ ∀ (h : p), q h
-/
#guard_msgs in
example (p : Prop) (q : p → Prop) : (h : p) → q h := by
  contrapose

/-! test contraposing `↔` -/

example (p q : Prop) (h : p ↔ q) : ¬p ↔ ¬q := by
  contrapose
  guard_target = p ↔ q
  exact h

example (p q : Prop) (h : ¬p ↔ q) : p ↔ ¬q := by
  contrapose
  guard_target = ¬p ↔ q
  exact h

example (p q : Prop) (h : p ↔ ¬q) : ¬p ↔ q := by
  contrapose
  guard_target = p ↔ ¬q
  exact h

example (p q : Prop) (h : p ↔ q) : ¬p ↔ ¬q := by
  contrapose
  guard_target = p ↔ q
  exact h

example (p q r : Prop) (h : ¬p ↔ ¬q ∧ ¬r) : p ↔ q ∨ r := by
  contrapose!
  guard_target = ¬p ↔ ¬q ∧ ¬r
  exact h

set_option contrapose.negate_iff false in
/--
error: Tactic `contrapose` failed: contraposing `↔` relations has been disabled.
To enable it, use `set_option contrapose.negate_iff true`.

p q : Prop
h : p ↔ q
⊢ ¬p ↔ ¬q
-/
#guard_msgs in
example (p q : Prop) (h : p ↔ q) : ¬p ↔ ¬q := by
  contrapose

/-! Test that we unfold reducible, but not semireducible definitions -/

example {α : Type} (a b : α) (p : Prop) (h : a = b → p) : ¬p → a ≠ b := by
  contrapose
  guard_target = a = b → p
  exact h

abbrev MyImp' (p q : Prop) := p → q
def MyImp := MyImp'
abbrev MyNot' (p : Prop) := ¬p
def MyNot := MyNot'

example (p q : Prop) (h : ¬q → ¬p) : MyImp p q := by
  fail_if_success contrapose
  unfold MyImp
  contrapose
  exact h

example (p q : Prop) (h : q → ¬p) : p → MyNot q := by
  fail_if_success (contrapose; exact h)
  unfold MyNot
  contrapose; exact h

example (p q r : Prop) (h' : ¬p ∨ ¬q) (h : p ∧ q) : r := by
  fail_if_success contrapose! +fdsewfjdsk h
  contrapose! +distrib h
  exact h'